mirror of
https://github.com/Kitware/CMake.git
synced 2026-01-08 06:40:48 -06:00
0e96a20478
Replace our hard-coded default for `/Zi` with a first-class abstraction to select the debug information format an enumeration of logical names. We've long hesitated to do this because the idea of "debug information format" touches on related concepts on several platforms. Avoid that scope creep by simply defining an abstraction that applies only when targeting the MSVC ABI on Windows. Removing the old default flag requires a policy because existing projects may rely on string processing to edit them and choose a runtime library under the old behavior. Add policy CMP0141 to provide compatibility. Fixes: #10189
47 lines
2.6 KiB
CMake
47 lines
2.6 KiB
CMake
macro(DebugInformationFormat_check tgt Debug_expect Release_expect MinSizeRel_expect RelWithDebInfo_expect)
|
|
set(vcProjectFile "${RunCMake_TEST_BINARY_DIR}/${tgt}.vcxproj")
|
|
if(NOT EXISTS "${vcProjectFile}")
|
|
set(RunCMake_TEST_FAILED "Project file ${tgt}.vcxproj does not exist.")
|
|
return()
|
|
endif()
|
|
|
|
set(Debug_actual "")
|
|
set(Release_actual "")
|
|
set(MinSizeRel_actual "")
|
|
set(RelWithDebInfo_actual "")
|
|
|
|
file(STRINGS "${vcProjectFile}" lines)
|
|
foreach(line IN LISTS lines)
|
|
if(line MATCHES "^ *<ItemDefinitionGroup Condition=\"'\\$\\(Configuration\\)\\|\\$\\(Platform\\)'=='([^<>]+)\\|[A-Za-z0-9_]+'\">")
|
|
set(Configuration "${CMAKE_MATCH_1}")
|
|
endif()
|
|
if(line MATCHES "^ *<DebugInformationFormat>([^<>]+)</DebugInformationFormat>")
|
|
set(${Configuration}_actual "${CMAKE_MATCH_1}")
|
|
endif()
|
|
endforeach()
|
|
|
|
if (NOT "${Debug_actual}" STREQUAL "${Debug_expect}")
|
|
set(RunCMake_TEST_FAILED "Project file ${tgt}.vcxproj Debug Configuration has DebugInformationFormat '${Debug_actual}', not '${Debug_expect}'.")
|
|
endif()
|
|
if (NOT "${Release_actual}" STREQUAL "${Release_expect}")
|
|
set(RunCMake_TEST_FAILED "Project file ${tgt}.vcxproj Release Configuration has DebugInformationFormat '${Release_actual}', not '${Release_expect}'.")
|
|
endif()
|
|
if (NOT "${MinSizeRel_actual}" STREQUAL "${MinSizeRel_expect}")
|
|
set(RunCMake_TEST_FAILED "Project file ${tgt}.vcxproj MinSizeRel Configuration has DebugInformationFormat '${MinSizeRel_actual}', not '${MinSizeRel_expect}'.")
|
|
endif()
|
|
if (NOT "${RelWithDebInfo_actual}" STREQUAL "${RelWithDebInfo_expect}")
|
|
set(RunCMake_TEST_FAILED "Project file ${tgt}.vcxproj RelWithDebInfo Configuration has DebugInformationFormat '${RelWithDebInfo_actual}', not '${RelWithDebInfo_expect}'.")
|
|
endif()
|
|
endmacro()
|
|
|
|
DebugInformationFormat_check(default-C ProgramDatabase "" "" ProgramDatabase)
|
|
DebugInformationFormat_check(default-CXX ProgramDatabase "" "" ProgramDatabase)
|
|
DebugInformationFormat_check(empty-C "" "" "" "")
|
|
DebugInformationFormat_check(empty-CXX "" "" "" "")
|
|
DebugInformationFormat_check(Embedded-C OldStyle OldStyle OldStyle OldStyle)
|
|
DebugInformationFormat_check(Embedded-CXX OldStyle OldStyle OldStyle OldStyle)
|
|
DebugInformationFormat_check(ProgramDatabase-C ProgramDatabase ProgramDatabase ProgramDatabase ProgramDatabase)
|
|
DebugInformationFormat_check(ProgramDatabase-CXX ProgramDatabase ProgramDatabase ProgramDatabase ProgramDatabase)
|
|
DebugInformationFormat_check(EditAndContinue-C EditAndContinue EditAndContinue EditAndContinue EditAndContinue)
|
|
DebugInformationFormat_check(EditAndContinue-CXX EditAndContinue EditAndContinue EditAndContinue EditAndContinue)
|