mirror of
https://github.com/Kitware/CMake.git
synced 2026-01-05 05:11:15 -06:00
0fedf1592c
This marks all `<PACKAGENAME>_FOUND` result variables as deprecated where possible (for `<PackageName>` find modules) to make it clearer which variable to use. In CMake 3.3, the FindPackageHandleStandardArgs module was refactored to set both `<PackageName>_FOUND` and uppercase `<PACKAGENAME>_FOUND` result variables to the same values. Before that, the FOUND_VAR argument could be used to set the result variable. * FindMatlab: Uppercased MATLAB_FOUND is not mentioned as it was never documented. * Documentation for FindPythonInterp and FindPythonLibs modules synced accordingly to their deprecation (3.12 instead of 4.2). * OPENGL_FOUND: deprecation version synced with other find modules. * DevIL_FOUND was introduced in CMake 3.8. The uppercased variant not mentioned as it was previously never documented. Fixes: #27242
90 lines
2.0 KiB
CMake
90 lines
2.0 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file LICENSE.rst or https://cmake.org/licensing for details.
|
|
|
|
#[=======================================================================[.rst:
|
|
FindPhysFS
|
|
----------
|
|
|
|
Finds the PhysicsFS library (PhysFS) for file I/O abstraction:
|
|
|
|
.. code-block:: cmake
|
|
|
|
find_package(PhysFS [...])
|
|
|
|
Result Variables
|
|
^^^^^^^^^^^^^^^^
|
|
|
|
This module defines the following variables:
|
|
|
|
``PhysFS_FOUND``
|
|
.. versionadded:: 3.3
|
|
|
|
Boolean indicating whether the PhysicsFS library was found.
|
|
|
|
Cache Variables
|
|
^^^^^^^^^^^^^^^
|
|
|
|
The following cache variables may also be set:
|
|
|
|
``PHYSFS_INCLUDE_DIR``
|
|
Directory containing the ``<physfs.h>`` and related headers needed for using
|
|
the library.
|
|
``PHYSFS_LIBRARY``
|
|
Path to the PhysicsFS library needed to link against.
|
|
|
|
Hints
|
|
^^^^^
|
|
|
|
This module accepts the following variables:
|
|
|
|
``PHYSFSDIR``
|
|
Environment variable that can be set to help locate a PhysicsFS library
|
|
installed in a custom location. It should point to the installation
|
|
destination that was used when configuring, building, and installing PhysicsFS
|
|
library: ``./configure --prefix=$PHYSFSDIR``.
|
|
|
|
Deprecated Variables
|
|
^^^^^^^^^^^^^^^^^^^^
|
|
|
|
The following variables are provided for backward compatibility:
|
|
|
|
``PHYSFS_FOUND``
|
|
.. deprecated:: 4.2
|
|
Use the ``PhysFS_FOUND``, which has the same value.
|
|
|
|
Boolean indicating whether the PhysicsFS library was found.
|
|
|
|
Examples
|
|
^^^^^^^^
|
|
|
|
Finding the PhysicsFS library:
|
|
|
|
.. code-block:: cmake
|
|
|
|
find_package(PhysFS)
|
|
#]=======================================================================]
|
|
|
|
find_path(PHYSFS_INCLUDE_DIR physfs.h
|
|
HINTS
|
|
ENV PHYSFSDIR
|
|
PATH_SUFFIXES include/physfs include
|
|
PATHS
|
|
~/Library/Frameworks
|
|
/Library/Frameworks
|
|
/opt
|
|
)
|
|
|
|
find_library(PHYSFS_LIBRARY
|
|
NAMES physfs
|
|
HINTS
|
|
ENV PHYSFSDIR
|
|
PATH_SUFFIXES lib
|
|
PATHS
|
|
~/Library/Frameworks
|
|
/Library/Frameworks
|
|
/opt
|
|
)
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(PhysFS DEFAULT_MSG PHYSFS_LIBRARY PHYSFS_INCLUDE_DIR)
|