mirror of
https://github.com/Kitware/CMake.git
synced 2025-12-31 10:50:16 -06:00
4e6a13f211
Where possible this syncs the CS for command names: - check_c_source_compiles() - check_cxx_compiler_flag() - check_cxx_source_compiles() - check_cxx_symbol_exists() - check_include_file_cxx() - check_include_file() - check_include_files() - check_library_exists() - check_source_compiles() - check_struct_has_member() - check_symbol_exists() - check_type_size() - cmake_dependent_option() - cmake_parse_arguments() - feature_summary() - file() - find_package_handle_standard_args() - if(), endif... - install(FILES) - list() - message() - pkg_check_modules() - select_library_configurations() - set_package_info() - test_big_endian()
58 lines
1.7 KiB
CMake
58 lines
1.7 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
#[=======================================================================[.rst:
|
|
FindGnuplot
|
|
-----------
|
|
|
|
this module looks for gnuplot
|
|
|
|
|
|
|
|
Once done this will define
|
|
|
|
::
|
|
|
|
GNUPLOT_FOUND - system has Gnuplot
|
|
GNUPLOT_EXECUTABLE - the Gnuplot executable
|
|
GNUPLOT_VERSION_STRING - the version of Gnuplot found (since CMake 2.8.8)
|
|
|
|
|
|
|
|
GNUPLOT_VERSION_STRING will not work for old versions like 3.7.1.
|
|
#]=======================================================================]
|
|
|
|
include(${CMAKE_CURRENT_LIST_DIR}/FindCygwin.cmake)
|
|
include(${CMAKE_CURRENT_LIST_DIR}/FindMsys.cmake)
|
|
|
|
find_program(GNUPLOT_EXECUTABLE
|
|
NAMES
|
|
gnuplot
|
|
pgnuplot
|
|
wgnupl32
|
|
PATHS
|
|
${CYGWIN_INSTALL_PATH}/bin
|
|
${MSYS_INSTALL_PATH}/usr/bin
|
|
)
|
|
|
|
if (GNUPLOT_EXECUTABLE)
|
|
execute_process(COMMAND "${GNUPLOT_EXECUTABLE}" --version
|
|
OUTPUT_VARIABLE GNUPLOT_OUTPUT_VARIABLE
|
|
ERROR_QUIET
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE)
|
|
|
|
string(REGEX REPLACE "^gnuplot ([0-9\\.]+)( patchlevel )?" "\\1." GNUPLOT_VERSION_STRING "${GNUPLOT_OUTPUT_VARIABLE}")
|
|
string(REGEX REPLACE "\\.$" "" GNUPLOT_VERSION_STRING "${GNUPLOT_VERSION_STRING}")
|
|
unset(GNUPLOT_OUTPUT_VARIABLE)
|
|
endif()
|
|
|
|
# for compatibility
|
|
set(GNUPLOT ${GNUPLOT_EXECUTABLE})
|
|
|
|
include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
|
|
find_package_handle_standard_args(Gnuplot
|
|
REQUIRED_VARS GNUPLOT_EXECUTABLE
|
|
VERSION_VAR GNUPLOT_VERSION_STRING)
|
|
|
|
mark_as_advanced( GNUPLOT_EXECUTABLE )
|