mirror of
https://github.com/Kitware/CMake.git
synced 2026-01-03 04:10:05 -06:00
c2341ece47
Prior to commit219dde4ea8(CheckPIESupported: now uses any SYSROOT settings, 2022-01-16, v3.23.0-rc1~110^2), the checks for `-pie` and `-no_pie` on macOS failed due to executing the compiler directly without any `-isysroot`, producing `ld: library not found for -lc++`. See issues #23053 and #19180. The failing check for `-pie` was a bug because it is supported on macOS, both for `x86_64` and `arm64`, and the commit fixed that check. However, `-no_pie` is not supported on macOS `arm64`. The above commit was only able to detect that due to commitf745e0497e(CheckCompilerFlags: Catch linker warning about ignored flags, 2022-01-03, v3.23.0-rc1~174^2), which we need to revert due to issue #23432. Instead, catch only the linker warning about the exact flag being checked.
53 lines
1.6 KiB
CMake
53 lines
1.6 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
include_guard(GLOBAL)
|
|
include(Internal/CheckFlagCommonConfig)
|
|
include(Internal/CheckSourceCompiles)
|
|
include(CMakeCheckCompilerFlagCommonPatterns)
|
|
|
|
cmake_policy(PUSH)
|
|
cmake_policy(SET CMP0054 NEW) # if() quoted variables not dereferenced
|
|
|
|
function(CMAKE_CHECK_LINKER_FLAG _lang _flag _var)
|
|
# link step supports less languages than the compiler
|
|
# so do a first check about the requested language
|
|
if (_lang STREQUAL "ISPC")
|
|
message (SEND_ERROR "check_linker_flag: ${_lang}: unsupported language.")
|
|
return()
|
|
endif()
|
|
|
|
# Parse extra arguments
|
|
cmake_parse_arguments(PARSE_ARGV 3 CHECK_LINKER_FLAG "" "OUTPUT_VARIABLE" "")
|
|
|
|
cmake_check_flag_common_init("check_linker_flag" ${_lang} _lang_src _lang_fail_regex)
|
|
|
|
set(CMAKE_REQUIRED_LINK_OPTIONS "${_flag}")
|
|
|
|
check_compiler_flag_common_patterns(_common_patterns)
|
|
|
|
# Match linker warnings if the exact flag is ignored.
|
|
foreach(flag IN LISTS _flag)
|
|
string(REGEX REPLACE "([][+.*?()^$])" [[\\\1]] _flag_regex "${flag}")
|
|
list(APPEND _common_patterns
|
|
FAIL_REGEX "warning: .*${_flag_regex}.* ignored"
|
|
)
|
|
endforeach()
|
|
|
|
cmake_check_source_compiles(${_lang}
|
|
"${_lang_src}"
|
|
${_var}
|
|
${_lang_fail_regex}
|
|
${_common_patterns}
|
|
OUTPUT_VARIABLE _output
|
|
)
|
|
|
|
if (CHECK_LINKER_FLAG_OUTPUT_VARIABLE)
|
|
set(${CHECK_LINKER_FLAG_OUTPUT_VARIABLE} "${_output}" PARENT_SCOPE)
|
|
endif()
|
|
|
|
cmake_check_flag_common_finish()
|
|
endfunction()
|
|
|
|
cmake_policy(POP)
|