mirror of
https://github.com/Kitware/CMake.git
synced 2026-01-13 01:39:58 -06:00
f53bd6f450
CMake 3.27 deprecates compatibility with CMake < 3.5. Update tests that do not cover older interfaces to avoid the deprecation warning. Follow the pattern from: * commit7b07ccdd2b(Tests/*Only: Update cmake_minimum_required versions, 2020-06-15, v3.19.0-rc1~629^2~1) * commit72e7c45e98(Tests: Bump CMake minimum required in tests to 2.8.12, 2020-12-22, v3.20.0-rc1~224^2) * commitf6b4db365a(Tests: bump cmake_minimum_required version to 2.8.12, 2021-04-04, v3.21.0-rc1~372^2) Also remove explicit `cmake_policy` settings made redundant by the version.
49 lines
1.9 KiB
CMake
49 lines
1.9 KiB
CMake
cmake_minimum_required(VERSION 3.5)
|
|
project(ModuleDefinition C)
|
|
|
|
# Test .def file source recognition for DLLs.
|
|
add_library(example_dll SHARED example_dll.c example_dll.def)
|
|
|
|
add_library(split_dll SHARED split_dll.c split_dll_1.def split_dll_2.def)
|
|
|
|
# Test generated .def file.
|
|
add_custom_command(OUTPUT example_dll_gen.def
|
|
DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/example_dll_gen.def.in
|
|
COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/example_dll_gen.def.in
|
|
${CMAKE_CURRENT_BINARY_DIR}/example_dll_gen.def
|
|
)
|
|
add_library(example_dll_gen SHARED example_dll_gen.c example_dll_gen.def)
|
|
|
|
# Test /DEF:<file> flag recognition for VS.
|
|
if(MSVC AND CMAKE_C_COMPILER_ID STREQUAL "IntelLLVM")
|
|
# IntelLLVM for MSVC frontend variant needs the /DEF flag wrapped to be sent
|
|
# to the linker, which happens automatically when the DEF file is added
|
|
# to the sources.
|
|
add_library(example_dll_2 SHARED
|
|
example_dll_2.c
|
|
"${ModuleDefinition_SOURCE_DIR}/example_dll_2.def"
|
|
)
|
|
set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS EXAMPLE_DLL_2)
|
|
set(example_dll_2 example_dll_2)
|
|
elseif(MSVC OR CMAKE_C_COMPILER_ID STREQUAL "Intel")
|
|
add_library(example_dll_2 SHARED example_dll_2.c)
|
|
set_property(TARGET example_dll_2 PROPERTY LINK_FLAGS
|
|
/DEF:"${ModuleDefinition_SOURCE_DIR}/example_dll_2.def")
|
|
set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS EXAMPLE_DLL_2)
|
|
set(example_dll_2 example_dll_2)
|
|
endif()
|
|
|
|
# Test .def file source recognition for EXEs.
|
|
add_executable(example_exe example_exe.c example_exe.def)
|
|
set_property(TARGET example_exe PROPERTY ENABLE_EXPORTS 1)
|
|
target_link_libraries(example_exe
|
|
example_dll
|
|
example_dll_gen
|
|
${example_dll_2}
|
|
split_dll
|
|
)
|
|
|
|
# Test linking to the executable.
|
|
add_library(example_mod_1 MODULE example_mod_1.c)
|
|
target_link_libraries(example_mod_1 example_exe example_dll ${example_dll_2})
|