mirror of
https://github.com/Kitware/CMake.git
synced 2026-01-08 14:50:10 -06:00
17e5516e60
The cost of setting up and executing a separate sub-build to do the download, update and patch steps required for FetchContent population can be significant with some platforms and CMake generators. Avoid the sub-build altogether by invoking the step scripts directly. Previously, if no generator was set (e.g. population was being done in script mode), a generator needed to be available on the default PATH. Since we no longer use a sub-build, this restriction is also now gone. Fixes: #21703
93 lines
2.8 KiB
CMake
93 lines
2.8 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
cmake_minimum_required(VERSION 3.5)
|
|
|
|
set(quiet "@quiet@")
|
|
set(script_dir "@CMAKE_CURRENT_FUNCTION_LIST_DIR@/ExternalProject")
|
|
include(${script_dir}/captured_process_setup.cmake)
|
|
|
|
if(NOT "@gitclone_infofile@" IS_NEWER_THAN "@gitclone_stampfile@")
|
|
if(NOT quiet)
|
|
message(STATUS
|
|
"Avoiding repeated git clone, stamp file is up to date: "
|
|
"'@gitclone_stampfile@'"
|
|
)
|
|
endif()
|
|
return()
|
|
endif()
|
|
|
|
execute_process(
|
|
COMMAND ${CMAKE_COMMAND} -E rm -rf "@source_dir@"
|
|
RESULT_VARIABLE error_code
|
|
${capture_output}
|
|
)
|
|
_ep_command_check_result(
|
|
error_code "Failed to remove directory: '@source_dir@'"
|
|
)
|
|
|
|
# try the clone 3 times in case there is an odd git clone issue
|
|
set(error_code 1)
|
|
set(number_of_tries 0)
|
|
while(error_code AND number_of_tries LESS 3)
|
|
# If you are seeing the following call hang and you have QUIET enabled, try
|
|
# turning QUIET off to show any output immediately. The command may be
|
|
# blocking while waiting for user input (e.g. a password to a SSH key).
|
|
execute_process(
|
|
COMMAND "@git_EXECUTABLE@" @git_options@
|
|
clone @git_clone_options@ "@git_repository@" "@src_name@"
|
|
WORKING_DIRECTORY "@work_dir@"
|
|
RESULT_VARIABLE error_code
|
|
${capture_output}
|
|
)
|
|
if(NOT "${out_var}" STREQUAL "")
|
|
string(APPEND accumulated_output "${out_var}\n")
|
|
endif()
|
|
math(EXPR number_of_tries "${number_of_tries} + 1")
|
|
endwhile()
|
|
if(number_of_tries GREATER 1)
|
|
set(msg "Had to git clone more than once: ${number_of_tries} times.")
|
|
if(quiet)
|
|
string(APPEND accumulated_output "${msg}\n")
|
|
else()
|
|
message(STATUS "${msg}")
|
|
endif()
|
|
endif()
|
|
_ep_command_check_result(
|
|
error_code "Failed to clone repository: '@git_repository@'"
|
|
)
|
|
|
|
execute_process(
|
|
COMMAND "@git_EXECUTABLE@" @git_options@
|
|
checkout "@git_tag@" @git_checkout_explicit--@
|
|
WORKING_DIRECTORY "@work_dir@/@src_name@"
|
|
RESULT_VARIABLE error_code
|
|
${capture_output}
|
|
)
|
|
_ep_command_check_result(error_code "Failed to checkout tag: '@git_tag@'")
|
|
|
|
set(init_submodules @init_submodules@)
|
|
if(init_submodules)
|
|
execute_process(
|
|
COMMAND "@git_EXECUTABLE@" @git_options@
|
|
submodule update @git_submodules_recurse@ --init @git_submodules@
|
|
WORKING_DIRECTORY "@work_dir@/@src_name@"
|
|
RESULT_VARIABLE error_code
|
|
${capture_output}
|
|
)
|
|
_ep_command_check_result(
|
|
error_code "Failed to update submodules in: '@work_dir@/@src_name@'"
|
|
)
|
|
endif()
|
|
|
|
# Complete success, update the script-last-run stamp file:
|
|
#
|
|
execute_process(
|
|
COMMAND ${CMAKE_COMMAND} -E copy "@gitclone_infofile@" "@gitclone_stampfile@"
|
|
RESULT_VARIABLE error_code
|
|
${capture_output}
|
|
)
|
|
_ep_command_check_result(
|
|
error_code "Failed to copy script-last-run stamp file: '@gitclone_stampfile@'"
|
|
)
|