mirror of
https://github.com/Kitware/CMake.git
synced 2026-01-06 13:51:33 -06:00
9e24437c91
Apply the change from commit db35e3cfd6 (VS: Fix support for '/guard:cf'
linker flag for v142, 2019-01-24, v3.14.0-rc1~74^2~2) to the v143 flag
table.
The entry for `LinkControlFlowGuard` in `v143_Link.json` does not work
when used in a `.vcxproj` file. Drop our link flag table entries for
this toolset so that the flag will be passed via `AdditionalOptions`.
Also add a test case.
41 lines
1.3 KiB
CMake
41 lines
1.3 KiB
CMake
set(vcProjectFile "${RunCMake_TEST_BINARY_DIR}/ControlFlowGuardProject.vcxproj")
|
|
if(NOT EXISTS "${vcProjectFile}")
|
|
set(RunCMake_TEST_FAILED "Project file ControlFlowGuardProject.vcxproj does not exist.")
|
|
return()
|
|
endif()
|
|
|
|
set(Is_in_link_section 0)
|
|
set(HAS_ControlFlowGuardSetting 0)
|
|
|
|
file(STRINGS "${vcProjectFile}" lines)
|
|
foreach(line IN LISTS lines)
|
|
if(line MATCHES "^ *<LinkControlFlowGuard>([^<>]+)</LinkControlFlowGuard>")
|
|
set(RunCMake_TEST_FAILED "Project file ControlFlowGuardProject.vcxproj contains the invalid <LinkControlFlowGuard> link property.")
|
|
return()
|
|
break()
|
|
endif()
|
|
if(line MATCHES "^ *<Link>")
|
|
# The start of the link section of the vcxproj file
|
|
set(Is_in_link_section 1)
|
|
continue()
|
|
endif()
|
|
if(line MATCHES "^ *</Link>")
|
|
# The end of the link section of the vcxproj file
|
|
set(Is_in_link_section 0)
|
|
continue()
|
|
endif()
|
|
if(Is_in_link_section)
|
|
if(line MATCHES "^ *<AdditionalOptions>([^<>]+)</AdditionalOptions>")
|
|
if("${CMAKE_MATCH_1}" MATCHES ".*/guard:cf.*")
|
|
set(HAS_ControlFlowGuardSetting 1)
|
|
break()
|
|
endif()
|
|
endif()
|
|
endif()
|
|
endforeach()
|
|
|
|
if(NOT HAS_ControlFlowGuardSetting)
|
|
set(RunCMake_TEST_FAILED "Project file ControlFlowGuardProject.vcxproj does not have '/guard:cf' specified in the <AdditionalOptions> property.")
|
|
return()
|
|
endif()
|