mirror of
https://github.com/Kitware/CMake.git
synced 2025-12-30 10:20:56 -06:00
0fedf1592c
This marks all `<PACKAGENAME>_FOUND` result variables as deprecated where possible (for `<PackageName>` find modules) to make it clearer which variable to use. In CMake 3.3, the FindPackageHandleStandardArgs module was refactored to set both `<PackageName>_FOUND` and uppercase `<PACKAGENAME>_FOUND` result variables to the same values. Before that, the FOUND_VAR argument could be used to set the result variable. * FindMatlab: Uppercased MATLAB_FOUND is not mentioned as it was never documented. * Documentation for FindPythonInterp and FindPythonLibs modules synced accordingly to their deprecation (3.12 instead of 4.2). * OPENGL_FOUND: deprecation version synced with other find modules. * DevIL_FOUND was introduced in CMake 3.8. The uppercased variant not mentioned as it was previously never documented. Fixes: #27242
87 lines
2.1 KiB
CMake
87 lines
2.1 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file LICENSE.rst or https://cmake.org/licensing for details.
|
|
|
|
#[=======================================================================[.rst:
|
|
FindCVS
|
|
-------
|
|
|
|
Finds the Concurrent Versions System (CVS):
|
|
|
|
.. code-block:: cmake
|
|
|
|
find_package(CVS [...])
|
|
|
|
Result Variables
|
|
^^^^^^^^^^^^^^^^
|
|
|
|
This module defines the following variables:
|
|
|
|
``CVS_FOUND``
|
|
Boolean indicating whether the ``cvs`` command-line client was found.
|
|
|
|
Cache Variables
|
|
^^^^^^^^^^^^^^^
|
|
|
|
The following cache variables may also be set:
|
|
|
|
``CVS_EXECUTABLE``
|
|
Path to ``cvs`` command-line client.
|
|
|
|
Examples
|
|
^^^^^^^^
|
|
|
|
Finding CVS and executing it in a process:
|
|
|
|
.. code-block:: cmake
|
|
|
|
find_package(CVS)
|
|
if(CVS_FOUND)
|
|
execute_process(COMMAND ${CVS_EXECUTABLE} --help)
|
|
endif()
|
|
#]=======================================================================]
|
|
|
|
# CVSNT
|
|
|
|
get_filename_component(
|
|
CVSNT_TypeLib_Win32
|
|
"[HKEY_CLASSES_ROOT\\TypeLib\\{2BDF7A65-0BFE-4B1A-9205-9AB900C7D0DA}\\1.0\\0\\win32]"
|
|
PATH)
|
|
|
|
get_filename_component(
|
|
CVSNT_Services_EventMessagePath
|
|
"[HKEY_LOCAL_MACHINE\\SYSTEM\\ControlSet001\\Services\\Eventlog\\Application\\cvsnt;EventMessageFile]"
|
|
PATH)
|
|
|
|
# WinCVS (in case CVSNT was installed in the same directory)
|
|
|
|
get_filename_component(
|
|
WinCVS_Folder_Command
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Classes\\Folder\\shell\\wincvs\\command]"
|
|
PATH)
|
|
|
|
# TortoiseCVS (in case CVSNT was installed in the same directory)
|
|
|
|
get_filename_component(
|
|
TortoiseCVS_Folder_Command
|
|
"[HKEY_CLASSES_ROOT\\CVS\\shell\\open\\command]"
|
|
PATH)
|
|
|
|
get_filename_component(
|
|
TortoiseCVS_DefaultIcon
|
|
"[HKEY_CLASSES_ROOT\\CVS\\DefaultIcon]"
|
|
PATH)
|
|
|
|
find_program(CVS_EXECUTABLE cvs
|
|
${TortoiseCVS_DefaultIcon}
|
|
${TortoiseCVS_Folder_Command}
|
|
${WinCVS_Folder_Command}
|
|
${CVSNT_Services_EventMessagePath}
|
|
${CVSNT_TypeLib_Win32}
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\CVS\\Pserver;InstallPath]"
|
|
DOC "CVS command line client"
|
|
)
|
|
mark_as_advanced(CVS_EXECUTABLE)
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(CVS DEFAULT_MSG CVS_EXECUTABLE)
|